home *** CD-ROM | disk | FTP | other *** search
/ Merciful 5 / Merciful - Disc 5.iso / software / r / real_3d / real3dv3.3b.dms / real3dv3.3b.adf / RPL.LZH / RPL / dumpobj.rpl < prev    next >
Text File  |  1995-07-08  |  4KB  |  144 lines
  1. (
  2. ( Recursively scans through the object tree and prints out object attributes
  3. ( 
  4.  
  5. 1 CONSTANT DUMPOBJECTS
  6.  
  7. "objects.rpl" LOAD
  8. "locks.rpl" LOAD
  9.  
  10. 300 STRING sBuffer
  11.  
  12. : DmpStr ( sString aFile )
  13.     FETCH FPUTS 0 < IF
  14.         "Cannot write to a file" ERROR
  15.     ENDIF
  16. ;
  17.  
  18. : DmpNL ( aFile )
  19.     10 STRING tmp
  20.  
  21.     "|n" tmp SPRINTF
  22.     tmp SWAP DmpStr
  23. ;
  24.     
  25. : DmpAttr ( iStatus aFile )
  26.     SWAP
  27.     IF
  28.         " X " SWAP DmpStr
  29.     ELSE
  30.         " . " SWAP DmpStr
  31.     ENDIF
  32. ;
  33.  
  34. : DmpObjAttrs
  35.     PARAM 
  36.         VARIABLE iCnt    ( recursion depth
  37.         VARIABLE aFile    
  38.         VARIABLE aObject
  39.     ENDPARAM
  40.     VARIABLE iFlags
  41.     
  42.     ( handle indenting
  43.     iCnt FETCH 0 
  44.     DO
  45.         " " aFile DmpStr
  46.     LOOP
  47.  
  48.     ( name
  49.     aObject FETCH O.sNAME + "%-16s" sBuffer SPRINTF
  50.     sBuffer aFile DmpStr
  51.  
  52.     ( handle indenting
  53.     26 iCnt FETCH - 1 
  54.     DO
  55.         " " aFile DmpStr
  56.     LOOP
  57.  
  58.     "|" aFile DmpStr
  59.     
  60.     ( Boolean OR/AND 
  61.     aObject FETCH O.wTYPE + WFETCH wOT_AND = aFile DmpAttr
  62.  
  63.     ( Object Flags
  64.     aObject FETCH O.iFLAGS + FETCH DUP
  65.  
  66.     lOF_INVERTED   BAND aFile DmpAttr DUP
  67.     lOF_PAINTED    BAND aFile DmpAttr DUP
  68.     lOF_WFINVISIBL BAND aFile DmpAttr DUP
  69.     lOF_RTINVISIBL BAND aFile DmpAttr DUP
  70.     lOF_COLLINV    BAND aFile DmpAttr DUP
  71.     lOF_TEXTURE    BAND aFile DmpAttr DUP
  72.     lOF_PROTECTED  BAND aFile DmpAttr DUP
  73.     lOF_PROTECTL2  BAND aFile DmpAttr DUP
  74.     lOF_MOTION     BAND aFile DmpAttr DUP
  75.     lOF_LIGHTSOURC BAND aFile DmpAttr DUP
  76.     lOF_BBOX       BAND aFile DmpAttr DUP
  77.     lOF_HOLLOW     BAND aFile DmpAttr DUP
  78.     lOF_NOBP1      BAND aFile DmpAttr DUP
  79.     lOF_NOBP2      BAND aFile DmpAttr DUP
  80.     lOF_INFINITE   BAND aFile DmpAttr DUP
  81.     lOF_TRIMCURVE  BAND aFile DmpAttr DUP
  82.     lOF_SCENE      BAND aFile DmpAttr DUP
  83.     lOF_NOTREFL    BAND aFile DmpAttr DUP
  84.     lOF_MATTE      BAND aFile DmpAttr DUP
  85.     lOF_SHADOWLESS BAND aFile DmpAttr DUP
  86.     lOF_BUMPSHADOW BAND aFile DmpAttr
  87.     DROP
  88.     aFile DmpNL 
  89. ;
  90.  
  91. : DmpObj
  92.     PARAM 
  93.         VARIABLE aObj       ( object to be dumped 
  94.         VARIABLE iLevel     ( recursion level for indenting 
  95.         VARIABLE aFile
  96.     ENDPARAM
  97.  
  98.     ( Dump object attributes to a file
  99.     iLevel FETCH aFile FETCH aObj FETCH DmpObjAttrs
  100.  
  101.     ( recursively handle sub objects
  102.     aObj FETCH O_GETSUB
  103.     BEGIN DUP WHILE
  104.         DUP iLevel FETCH 1 + aFile FETCH DmpObj
  105.         O_GETNEXT 
  106.     REPEAT
  107.     DROP
  108. ;
  109.  
  110. : DmpObjects
  111.     PARAM
  112.         VARIABLE aFileName
  113.     ENDPARAM
  114.     VARIABLE aFile
  115.  
  116.     ( Open file 
  117.     aFileName FETCH "w" FOPEN DUP aFile STORE
  118.     NOT IF
  119.         aFileName FETCH "Cannot open file %s" ERROR
  120.     ENDIF
  121.  
  122.     ( Print out header
  123.  
  124.     "------------------------------------------------------------------------------------------------------------" aFile DmpStr aFile DmpNL
  125.     "                                         | Boolean  Invisib  M  Prot  M  L  B   Type    I  T  S  N  M Shadow" aFile DmpStr aFile DmpNL
  126.     "                                         | -------- -------  A  ----  B  I  B  -------  N  R  C  O  A ------" aFile DmpStr aFile DmpNL
  127.     "                                         | A  I  P  W  R  C  P  P  P  L  G  O  H  1  2  F  I  E  R  T  C  B " aFile DmpStr aFile DmpNL
  128.     "                                         | N  N  N  F  T  D  P  1  2  U  H  X  O  B  B  I  M  N  E  T  S  M " aFile DmpStr aFile DmpNL
  129.     " Objects                                 | D  V  T           I        R  T     L  P  P  N  C  E  F  E  T  P " aFile DmpStr aFile DmpNL
  130.     "------------------------------------------------------------------------------------------------------------" aFile DmpStr aFile DmpNL
  131.  
  132.     ( Dump objects
  133.     iLOCK_SHARED O_LOCK
  134.     O_GETROOT 1 aFile FETCH DmpObj
  135.     iLOCK_REMOVE O_LOCK
  136.  
  137.     ( close file
  138.     aFile FETCH FCLOSE
  139. ;
  140.  
  141. "ram:dump.txt" DmpObjects
  142.  
  143. FORGET DUMPOBJECTS
  144.